Quitar advertencia al enviar correos sin asunto Outlook 2010

Buenas taringa, ciertamente encontre este post suelto en una pagina gringa la verdad aca en la oficina nos resulto muy util, se trata de un simple codigo en vb que se aplica como una macros que quita la advertencia al enviar correos sin asunto con el Outlook 2010. Empiezo entonces...

Dentro de Outlook presionan Alt+F11 para abrir el editor

Una vez asi ven la vista en arbol que hay a la izquierda, abren todo para llegar a ThisOutlookSession y lo abren con Doble Clic y ahi les aparece el lugar donde tienen que pegar el codigo




Option Explicit
 
'=========================================================================
' Prevents Outlook® 2010 to display a no-subject warning message
' (c) Peter Marchert - http://www.outlook-stuff.com
' 2010-07-15 Version 1.0.0
' 2010-07-19 Version 1.0.1
'=========================================================================
 
Private WithEvents colInspectors As Outlook.Inspectors
 
Private Sub Application_Startup()
 
    '---------------------------------------------------------------------
    ' Set a reference to all forms
    '---------------------------------------------------------------------
    Set colInspectors = Outlook.Inspectors
 
End Sub
 
Private Sub colInspectors_NewInspector(ByVal Inspector As Inspector)
 
    '---------------------------------------------------------------------
    ' This code is running if a form (e. g. an e-mail) will be opened
    '---------------------------------------------------------------------
 
    Dim objItem As Object
 
    '---------------------------------------------------------------------
    ' Skip errors
    '---------------------------------------------------------------------
    On Error GoTo ExitProc
 
    '---------------------------------------------------------------------
    ' Set a reference to the open item
    '---------------------------------------------------------------------
    Set objItem = Inspector.CurrentItem
 
    '---------------------------------------------------------------------
    ' A new item does not have a received time
    '---------------------------------------------------------------------
    If Year(objItem.ReceivedTime) = 4501 Then
 
        '-----------------------------------------------------------------
        ' Check if the subject is empty if an e-mail was created by a
        ' template with predefined subject.
        '-----------------------------------------------------------------
        If objItem.Subject = "" Then objItem.Subject = " "
 
    End If
 
ExitProc:
 
    '---------------------------------------------------------------------
    ' Delete the reference to the form and to the item
    '---------------------------------------------------------------------
    Set objItem = Nothing
    Set Inspector = Nothing
 
End Sub
 
Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
 
    On Error Resume Next
 
    '---------------------------------------------------------------------
    ' If the blank still exists it will now be removed (Outlook®
    ' will this not recognize)
    '---------------------------------------------------------------------
    Item.Subject = Trim(Item.Subject)
 
End Sub
 
Private Sub Application_Quit()
 
    '---------------------------------------------------------------------
    ' Delete the reference to the forms
    '---------------------------------------------------------------------
    Set colInspectors = Nothing
 
End Sub


Ahora ponen Guardar y cierran este editor.

Ahora vamos a Archivos -> Opciones -> Centro de Confianza y cliquean en el boton enmarcado abajo



Ahora van a Configuracion de Macros, y configuran todo como esta en la imagen.



le dan a Aceptar -> Aceptar

Y por ultimo reinician (cerrar abrir) outlook y woala!. Ya pueden enviar correos sin asunto sin que outlook los moleste con la advertencia.

Saludos y espero que les sea util. Bye!